デザインパターンのうちの一つである Singletonパターンは「指定したクラスのインスタンスが一つしか存在しないことを保証したい」場合に用いる、と文献に書いてあります。Singletonを適用したクラスのインスタンスをnewで生成しようとするとコンパイラがエラーを出して知らせてくれる、というものです。この用途では、結構大規模なプロジェクトではないと Singletonパターンを利用することは無いかなあ、と当初は考えスルーしてしまっておりました。

しかし Singletonパターンを用いると「どのクラスからも直に Singletonパターンを用いたクラスのインスタンスを 取得する事が可能になる」という用途もあることに気づきました。

一つしかインスタンスを生成しないＡというクラスがあり、クラスＡの機能を利用したいＢというクラスがあるとします。

クラスＡに Singletonパターンを適用しない場合、クラスＢは、どこかのクラスで一度生成されたクラスＡのインスタンスを、引数経由で取得します。ここで、クラスＢのインスタンスが Ｃというクラス内で生成され、クラスＣはクラスＡの機能をまったく利用しない場合、クラスＣには クラスＡのインスタンスをクラスＢへ受け渡すための通路を用意する必要があり、クラスＣには不必要なクラスＡに関する記述を用意する必要がでてきてしまいます。

クラスＡに Singletonパターンを適用する場合、クラスＢは引数経由でクラスＡのインスタンスを取得する必要がなくなります。ここで、クラスＢのインスタンスが Ｃというクラス内で生成される場合、クラスＣ内にはクラスＡに関する記述はまったく必要がなくなります。

Singletonパターンを用いた簡単な例は以下の通りです。AS3では Singletonパターンの記述がやや困難なものになるようなので AS2で記述しています。上記例で言うと、ControlクラスがＡ、PersonクラスががＢ、UserクラスがＣ、となります。Mainクラスが Controlクラス(Ａ)とUserクラス(Ｃ)を生成するメインとなるクラスです。
PersonクラスがControlクラス内に設定された文字列を利用したい場合のプログラムです。

//メインクラス
class Main {

	//初めに呼び出される
	public function Main(){
		
		var ctrl:Control = Control.getInstance();
		ctrl.init( "test" );
		
		var user:User = new User();
	}
}

//Ａ : Singleton適用
class Control {
	
	private static var instance:Control = new Control();

	private var str:String;
	public function get _str():String{ return this.str; }
	
	private function Control(){}
	
	public static function getInstance():Control{
		return instance;
	}
	
	public function init( str:String ):Void{
		this.str = str;
	}
}

//Ｃ : Ｂを生成するクラス
class User {
	
	public function User(){
		new Person();
	}
}

//Ｂ : クラスＡの機能を利用するクラス
class Person {
	
	public function Person(){
		var ctrl:Control = Control.getInstance();
		trace(ctrl._str); //testと出力される
	}	
}

Singletonパターンを用いない場合、Controlクラスのインスタンスを Userクラスのコンストラクタに引数で受け渡し、UserクラスからPersonクラスのコンストラクタの引数へ Controlクラスのインスタンスを受け渡す、という記述になります。Userクラスでは Controlクラスの機能は利用しないのに Controlクラスに関する記述が必要になってしまいます。

■AS3でのSingletonパターン記述法
akihiro kamijo : コンストラクタ （と Singleton）

[ FLASH ] [ tips ] 投稿者 siratama : 2007年01月28日 16:11